| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: install.pri 109 2010-04-27 07:12:55Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/install.pri $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | # Common rules |
|---|
| 14 | l10n.files = l10n/*.qm |
|---|
| 15 | #share.files = |
|---|
| 16 | docs.files = COPYING README.txt |
|---|
| 17 | INSTALLS += target l10n share docs |
|---|
| 18 | |
|---|
| 19 | # For *nix: |
|---|
| 20 | # - executable goes to /usr/bin |
|---|
| 21 | # - COPYING and README go to /usr/share/TSPSG |
|---|
| 22 | # - translations go to /usr/share/TSPSG/l10n |
|---|
| 23 | # - docs go to /usr/share/doc/TSPSG-x.x.x |
|---|
| 24 | unix:!symbian { |
|---|
| 25 | PREFIX = /usr |
|---|
| 26 | CONFIG(release, debug|release) { |
|---|
| 27 | DEFINES += PATH_L10N=\\\"$$PREFIX/share/TSPSG/l10n\\\" |
|---|
| 28 | DEFINES += PATH_DOCS=\\\"$$PREFIX/share/TSPSG/docs\\\" |
|---|
| 29 | } |
|---|
| 30 | |
|---|
| 31 | target.path = $$PREFIX/bin |
|---|
| 32 | share.path = $$PREFIX/share/TSPSG |
|---|
| 33 | l10n.path = $$PREFIX/share/TSPSG/l10n |
|---|
| 34 | docs.path = $$PREFIX/share/doc/TSPSG-$$VERSION |
|---|
| 35 | apps.files = resources/tspsg.desktop |
|---|
| 36 | apps.path = $$PREFIX/share/applications/ |
|---|
| 37 | icon.files = resources/tspsg.png |
|---|
| 38 | icon.path = $$PREFIX/share/pixmaps |
|---|
| 39 | INSTALLS += apps icon |
|---|
| 40 | } |
|---|
| 41 | |
|---|
| 42 | # TODO: MacOSX |
|---|
| 43 | |
|---|
| 44 | # For win32: everything goes to "%PROGRAMFILES%\TSPSG" and subfolders. |
|---|
| 45 | win32 { |
|---|
| 46 | PREFIX = "$$(PROGRAMFILES)" |
|---|
| 47 | |
|---|
| 48 | share.files = $$[QT_INSTALL_BINS]/QtCore$${D}4.dll \ |
|---|
| 49 | $$[QT_INSTALL_BINS]/QtGui$${D}4.dll |
|---|
| 50 | !nosvg { |
|---|
| 51 | share.files += $$[QT_INSTALL_BINS]/QtSvg$${D}4.dll |
|---|
| 52 | } |
|---|
| 53 | l10n.files += $$[QT_INSTALL_TRANSLATIONS]/*.qm |
|---|
| 54 | win32-g++ { |
|---|
| 55 | share.files += $$[QT_INSTALL_BINS]/mingwm10.dll \ |
|---|
| 56 | $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll |
|---|
| 57 | } |
|---|
| 58 | imageformats.files = $$[QT_INSTALL_PLUGINS]/imageformats/qjpeg$${D}4.dll \ |
|---|
| 59 | $$[QT_INSTALL_PLUGINS]/imageformats/qtiff$${D}4.dll |
|---|
| 60 | imageformats.path = $$PREFIX/TSPSG/imageformats |
|---|
| 61 | INSTALLS += imageformats |
|---|
| 62 | } |
|---|
| 63 | |
|---|
| 64 | # For wince: we are deploying to \Program Files\TSPSG. |
|---|
| 65 | wince { |
|---|
| 66 | PREFIX = "\Program Files" |
|---|
| 67 | share.sources = $$share.files |
|---|
| 68 | l10n.sources = $$l10n.files \ |
|---|
| 69 | $$[QT_INSTALL_TRANSLATIONS]/*.qm |
|---|
| 70 | docs.sources = $$docs.files |
|---|
| 71 | |
|---|
| 72 | DEPLOYMENT += target share l10n docs |
|---|
| 73 | # DEPLOYMENT_PLUGIN += qjpeg qtiff |
|---|
| 74 | } |
|---|
| 75 | |
|---|
| 76 | # win32 and wince common |
|---|
| 77 | win* { |
|---|
| 78 | target.path = $$PREFIX/TSPSG |
|---|
| 79 | share.path = $$PREFIX/TSPSG |
|---|
| 80 | l10n.path = $$PREFIX/TSPSG/l10n |
|---|
| 81 | docs.path = $$PREFIX/TSPSG |
|---|
| 82 | |
|---|
| 83 | RC_FILE = resources/tspsg.rc |
|---|
| 84 | } |
|---|
| 85 | |
|---|
| 86 | # Symbian |
|---|
| 87 | symbian { |
|---|
| 88 | # qmake for Symbian (as of Qt 4.6.2) has a bug: file masks doesn't work, so we need to specify all files manually |
|---|
| 89 | share.sources = $$share.files |
|---|
| 90 | l10n.sources = $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \ |
|---|
| 91 | $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm \ |
|---|
| 92 | l10n/tspsg_en.qm l10n/tspsg_ru.qm l10n/tspsg_uk.qm |
|---|
| 93 | l10n.path = l10n |
|---|
| 94 | docs.sources = $$docs.files |
|---|
| 95 | docs.pkg_prerules = \ |
|---|
| 96 | "\"README.txt\" - \"\", FILETEXT, TEXTCONTINUE" \ |
|---|
| 97 | "\"COPYING\" - \"\", FILETEXT, TEXTEXIT" |
|---|
| 98 | DEPLOYMENT += share l10n docs |
|---|
| 99 | # DEPLOYMENT_PLUGIN += qjpeg qtiff |
|---|
| 100 | |
|---|
| 101 | ICON = resources/tspsg.svg |
|---|
| 102 | |
|---|
| 103 | appinfo = \ |
|---|
| 104 | "$$LITERAL_HASH{\"TSPSG\"},(0xEb9dce0e),$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE" |
|---|
| 105 | vendorinfo = \ |
|---|
| 106 | "%{\"l-homes.org\"}" \ |
|---|
| 107 | ":\"l-homes.org\"" |
|---|
| 108 | default_deployment.pkg_prerules = appinfo vendorinfo |
|---|
| 109 | DEPLOYMENT.installer_header = "$${LITERAL_HASH}{\"TSPSG Installer\"},(0xA000D7CE),1,0,0" |
|---|
| 110 | } |
|---|
