| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: install.pri 137 2010-09-15 14:57:37Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/install.pri $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | # Common rules |
|---|
| 14 | #l10n.files = l10n/*.qm |
|---|
| 15 | #share.files = |
|---|
| 16 | docs.files = COPYING ChangeLog.txt README.txt INSTALL.txt |
|---|
| 17 | INSTALLS += target share docs # l10n |
|---|
| 18 | |
|---|
| 19 | # For *nix: |
|---|
| 20 | # - executable goes to /usr/bin |
|---|
| 21 | # - COPYING and README go to /usr/share/TSPSG |
|---|
| 22 | # - translations go to /usr/share/TSPSG/l10n |
|---|
| 23 | # - docs go to /usr/share/doc/TSPSG-x.x.x |
|---|
| 24 | unix:!macx:!symbian { |
|---|
| 25 | PREFIX = /usr |
|---|
| 26 | CONFIG(release, debug|release) { |
|---|
| 27 | DEFINES += PATH_L10N=\\\"$$PREFIX/share/TSPSG/l10n\\\" |
|---|
| 28 | DEFINES += PATH_DOCS=\\\"$$PREFIX/share/TSPSG/docs\\\" |
|---|
| 29 | } |
|---|
| 30 | |
|---|
| 31 | target.path = $$PREFIX/bin |
|---|
| 32 | share.path = $$PREFIX/share/TSPSG |
|---|
| 33 | # l10n.path = $$PREFIX/share/TSPSG/l10n |
|---|
| 34 | docs.path = $$PREFIX/share/doc/TSPSG-$$VERSION |
|---|
| 35 | apps.files = resources/tspsg.desktop |
|---|
| 36 | apps.path = $$PREFIX/share/applications/ |
|---|
| 37 | icon.files = resources/tspsg.png |
|---|
| 38 | icon.path = $$PREFIX/share/pixmaps |
|---|
| 39 | INSTALLS += apps icon |
|---|
| 40 | } |
|---|
| 41 | |
|---|
| 42 | # TODO: MacOSX |
|---|
| 43 | macx { |
|---|
| 44 | } |
|---|
| 45 | |
|---|
| 46 | # For win32: everything goes to "%PROGRAMFILES%\TSPSG" and subfolders. |
|---|
| 47 | win32 { |
|---|
| 48 | PREFIX = "$$(PROGRAMFILES)" |
|---|
| 49 | |
|---|
| 50 | share.files = $$[QT_INSTALL_BINS]/QtCore$${D}4.dll \ |
|---|
| 51 | $$[QT_INSTALL_BINS]/QtGui$${D}4.dll |
|---|
| 52 | !nosvg { |
|---|
| 53 | share.files += $$[QT_INSTALL_BINS]/QtSvg$${D}4.dll |
|---|
| 54 | } |
|---|
| 55 | # l10n.files += $$[QT_INSTALL_TRANSLATIONS]/*.qm |
|---|
| 56 | win32-g++ { |
|---|
| 57 | share.files += $$[QT_INSTALL_BINS]/mingwm10.dll \ |
|---|
| 58 | $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll |
|---|
| 59 | } |
|---|
| 60 | # iconengines.files = $$[QT_INSTALL_PLUGINS]/iconengines/qsvgicon$${D}4.dll |
|---|
| 61 | # iconengines.path = $$PREFIX/TSPSG/iconengines |
|---|
| 62 | imageformats.files = $$[QT_INSTALL_PLUGINS]/imageformats/qjpeg$${D}4.dll \ |
|---|
| 63 | $$[QT_INSTALL_PLUGINS]/imageformats/qtiff$${D}4.dll |
|---|
| 64 | imageformats.path = $$PREFIX/TSPSG/imageformats |
|---|
| 65 | INSTALLS += imageformats # iconengines |
|---|
| 66 | } |
|---|
| 67 | |
|---|
| 68 | # For wince: we are deploying to \Program Files\TSPSG. |
|---|
| 69 | wince* { |
|---|
| 70 | PREFIX = "\\Program Files" |
|---|
| 71 | share.sources = $$share.files |
|---|
| 72 | # l10n.sources = $$l10n.files \ |
|---|
| 73 | # $$[QT_INSTALL_TRANSLATIONS]/*.qm |
|---|
| 74 | docs.sources = $$docs.files |
|---|
| 75 | |
|---|
| 76 | DEPLOYMENT += target share docs # l10n |
|---|
| 77 | # DEPLOYMENT_PLUGIN += qjpeg qtiff qsvgicon |
|---|
| 78 | } |
|---|
| 79 | |
|---|
| 80 | # win32 and wince common |
|---|
| 81 | win* { |
|---|
| 82 | target.path = $$PREFIX/TSPSG |
|---|
| 83 | share.path = $$PREFIX/TSPSG |
|---|
| 84 | # l10n.path = $$PREFIX/TSPSG/l10n |
|---|
| 85 | docs.path = $$PREFIX/TSPSG |
|---|
| 86 | |
|---|
| 87 | RC_FILE = resources/tspsg.rc |
|---|
| 88 | } |
|---|
| 89 | |
|---|
| 90 | # Symbian |
|---|
| 91 | symbian { |
|---|
| 92 | # qmake for Symbian (as of Qt 4.6.2) has a bug: file masks doesn't work, so we need to specify all files manually |
|---|
| 93 | share.sources = $$share.files |
|---|
| 94 | # l10n.sources = $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \ |
|---|
| 95 | # $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm \ |
|---|
| 96 | # l10n/tspsg_en.qm l10n/tspsg_ru.qm l10n/tspsg_uk.qm |
|---|
| 97 | # l10n.path = l10n |
|---|
| 98 | docs.sources = $$docs.files |
|---|
| 99 | docs.pkg_prerules = \ |
|---|
| 100 | "\"README.txt\" - \"\", FILETEXT, TEXTCONTINUE" \ |
|---|
| 101 | "\"COPYING\" - \"\", FILETEXT, TEXTEXIT" |
|---|
| 102 | DEPLOYMENT += share docs # l10n |
|---|
| 103 | # DEPLOYMENT_PLUGIN += qjpeg qtiff qsvgicon |
|---|
| 104 | |
|---|
| 105 | ICON = resources/tspsg.svg |
|---|
| 106 | |
|---|
| 107 | appinfo = \ |
|---|
| 108 | "$$LITERAL_HASH{\"TSPSG\"},(0xEb9dce0e),$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE" |
|---|
| 109 | vendorinfo = \ |
|---|
| 110 | "%{\"l-homes.org\"}" \ |
|---|
| 111 | ":\"l-homes.org\"" |
|---|
| 112 | default_deployment.pkg_prerules = appinfo vendorinfo |
|---|
| 113 | DEPLOYMENT.installer_header = "$${LITERAL_HASH}{\"TSPSG Installer\"},(0xA000D7CE),1,0,0" |
|---|
| 114 | } |
|---|
