| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: tspsg.pro 117 2010-05-02 10:51:20Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/tspsg.pro $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | TEMPLATE = app |
|---|
| 20 | |
|---|
| 21 | # Versioning |
|---|
| 22 | BUILD_VERSION_MAJOR = 0 |
|---|
| 23 | BUILD_VERSION_MINOR = 1 |
|---|
| 24 | BUILD_RELEASE = 3 |
|---|
| 25 | |
|---|
| 26 | # These are only defined on releases |
|---|
| 27 | #DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 28 | #!symbian { |
|---|
| 29 | # DEFINES += BUILD_STATUS="\"(alpha 2)\"" |
|---|
| 30 | #} else { |
|---|
| 31 | # # Symbian doesn't handle spaces in defines well |
|---|
| 32 | # DEFINES += BUILD_STATUS="(alpha2)" |
|---|
| 33 | #} |
|---|
| 34 | |
|---|
| 35 | #REVISION = 100 |
|---|
| 36 | REVISION = $$system(svnversion) |
|---|
| 37 | REVISION = $$replace(REVISION,":","") |
|---|
| 38 | REVISION = $$replace(REVISION,"M","") |
|---|
| 39 | #VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION) |
|---|
| 40 | win32-msvc* { |
|---|
| 41 | VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 42 | } else { |
|---|
| 43 | VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION) |
|---|
| 44 | } |
|---|
| 45 | |
|---|
| 46 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 47 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 48 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 49 | BUILD_NUMBER=$$REVISION |
|---|
| 50 | |
|---|
| 51 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 52 | unix:!symbian { |
|---|
| 53 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 54 | } else:unix { |
|---|
| 55 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 56 | } else { |
|---|
| 57 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 58 | } |
|---|
| 59 | include($$join(PRL, "/")) |
|---|
| 60 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 61 | # We "embed" JPEG and TIFF support on static build |
|---|
| 62 | DEFINES += STATIC_BUILD |
|---|
| 63 | # QTPLUGIN += qjpeg qtiff |
|---|
| 64 | } |
|---|
| 65 | |
|---|
| 66 | CONFIG(release, debug|release) { |
|---|
| 67 | OBJECTS_DIR = release |
|---|
| 68 | DESTDIR = release |
|---|
| 69 | D = |
|---|
| 70 | } else { |
|---|
| 71 | OBJECTS_DIR = debug |
|---|
| 72 | DESTDIR = debug |
|---|
| 73 | DEFINES += DEBUG |
|---|
| 74 | # CONFIG += console |
|---|
| 75 | D = d |
|---|
| 76 | } |
|---|
| 77 | TARGET = tspsg$${D} |
|---|
| 78 | |
|---|
| 79 | # Saving all intermediate files to tmp directory. |
|---|
| 80 | MOC_DIR = ./tmp |
|---|
| 81 | RCC_DIR = ./tmp |
|---|
| 82 | UI_DIR = ./tmp |
|---|
| 83 | |
|---|
| 84 | # Include 3rd party libraries |
|---|
| 85 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 86 | |
|---|
| 87 | # Include file(s) |
|---|
| 88 | include(tspsg.pri) |
|---|
| 89 | |
|---|
| 90 | # Installation and deployment |
|---|
| 91 | include(install.pri) |
|---|
