| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: tspsg.pro 109 2010-04-27 07:12:55Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/tspsg.pro $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | TEMPLATE = app |
|---|
| 20 | |
|---|
| 21 | # Versioning |
|---|
| 22 | BUILD_VERSION_MAJOR = 0 |
|---|
| 23 | BUILD_VERSION_MINOR = 1 |
|---|
| 24 | BUILD_RELEASE = 3 |
|---|
| 25 | |
|---|
| 26 | # These are only defined on releases |
|---|
| 27 | #DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 28 | #!symbian { |
|---|
| 29 | # DEFINES += BUILD_STATUS="\"(alpha 2)\"" |
|---|
| 30 | #} else { |
|---|
| 31 | # # Symbian doesn't handle spaces in defines well |
|---|
| 32 | # DEFINES += BUILD_STATUS="(alpha2)" |
|---|
| 33 | #} |
|---|
| 34 | |
|---|
| 35 | #REVISION = 100 |
|---|
| 36 | REVISION = $$system(svnversion) |
|---|
| 37 | REVISION = $$replace(REVISION,"M","") |
|---|
| 38 | VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION) |
|---|
| 39 | |
|---|
| 40 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 41 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 42 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 43 | BUILD_NUMBER=$$REVISION |
|---|
| 44 | |
|---|
| 45 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 46 | unix:!symbian { |
|---|
| 47 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 48 | } else:unix { |
|---|
| 49 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 50 | } else { |
|---|
| 51 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 52 | } |
|---|
| 53 | include($$join(PRL, "/")) |
|---|
| 54 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 55 | # We "embed" JPEG and TIFF support on static build |
|---|
| 56 | DEFINES += STATIC_BUILD |
|---|
| 57 | # QTPLUGIN += qjpeg qtiff |
|---|
| 58 | } |
|---|
| 59 | |
|---|
| 60 | CONFIG(release, debug|release) { |
|---|
| 61 | OBJECTS_DIR = release |
|---|
| 62 | DESTDIR = release |
|---|
| 63 | D = |
|---|
| 64 | } else { |
|---|
| 65 | OBJECTS_DIR = debug |
|---|
| 66 | DESTDIR = debug |
|---|
| 67 | DEFINES += DEBUG |
|---|
| 68 | # CONFIG += console |
|---|
| 69 | D = d |
|---|
| 70 | } |
|---|
| 71 | TARGET = tspsg$${D} |
|---|
| 72 | |
|---|
| 73 | # Saving all intermediate files to tmp directory. |
|---|
| 74 | MOC_DIR = ./tmp |
|---|
| 75 | RCC_DIR = ./tmp |
|---|
| 76 | UI_DIR = ./tmp |
|---|
| 77 | |
|---|
| 78 | # Include file(s) |
|---|
| 79 | include(tspsg.pri) |
|---|
| 80 | |
|---|
| 81 | # Installation and deployment |
|---|
| 82 | include(install.pri) |
|---|
