| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: tspsg.pro 139 2010-09-29 21:21:46Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/tspsg.pro $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | TEMPLATE = app |
|---|
| 20 | |
|---|
| 21 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 22 | |
|---|
| 23 | # Version information |
|---|
| 24 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 25 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 26 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 27 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2010 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 28 | |
|---|
| 29 | # Versioning |
|---|
| 30 | BUILD_VERSION_MAJOR = 0 |
|---|
| 31 | BUILD_VERSION_MINOR = 1 |
|---|
| 32 | BUILD_RELEASE = 3 |
|---|
| 33 | |
|---|
| 34 | # These are only defined on releases |
|---|
| 35 | #DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 36 | #!symbian { |
|---|
| 37 | # DEFINES += BUILD_STATUS="\"(alpha 2)\"" |
|---|
| 38 | #} else { |
|---|
| 39 | # # Symbian doesn't handle spaces in defines well |
|---|
| 40 | # DEFINES += BUILD_STATUS="(alpha2)" |
|---|
| 41 | #} |
|---|
| 42 | |
|---|
| 43 | #REVISION = 100 |
|---|
| 44 | REVISION = $$system(svnversion) |
|---|
| 45 | REVISION = $$replace(REVISION,":","") |
|---|
| 46 | REVISION = $$replace(REVISION,"M","") |
|---|
| 47 | win32-msvc*|wincewm* { |
|---|
| 48 | VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 49 | } else { |
|---|
| 50 | VERSION = $$sprintf("%1.%2.%3.%4",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE,$$REVISION) |
|---|
| 51 | } |
|---|
| 52 | |
|---|
| 53 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 54 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 55 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 56 | BUILD_NUMBER=$$REVISION |
|---|
| 57 | |
|---|
| 58 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 59 | macx { |
|---|
| 60 | PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl |
|---|
| 61 | } else:symbian { |
|---|
| 62 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 63 | } else:unix { |
|---|
| 64 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 65 | } else { |
|---|
| 66 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 67 | } |
|---|
| 68 | include($$join(PRL, "/")) |
|---|
| 69 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 70 | # We "embed" SVG icon, JPEG and TIFF support on static build |
|---|
| 71 | DEFINES += STATIC_BUILD |
|---|
| 72 | # !nosvg:QTPLUGIN += qsvgicon |
|---|
| 73 | } |
|---|
| 74 | |
|---|
| 75 | CONFIG(release, debug|release) { |
|---|
| 76 | OBJECTS_DIR = release |
|---|
| 77 | D = |
|---|
| 78 | } else { |
|---|
| 79 | OBJECTS_DIR = debug |
|---|
| 80 | DEFINES += DEBUG |
|---|
| 81 | # CONFIG += console |
|---|
| 82 | D = d |
|---|
| 83 | } |
|---|
| 84 | DESTDIR = bin |
|---|
| 85 | TARGET = tspsg$${D} |
|---|
| 86 | |
|---|
| 87 | # Saving all intermediate files to tmp directory. |
|---|
| 88 | MOC_DIR = tmp |
|---|
| 89 | RCC_DIR = tmp |
|---|
| 90 | UI_DIR = tmp |
|---|
| 91 | |
|---|
| 92 | # Include 3rd party libraries |
|---|
| 93 | !wincewm*:!symbian { |
|---|
| 94 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 95 | } |
|---|
| 96 | |
|---|
| 97 | win32:LIBS += -lole32 |
|---|
| 98 | |
|---|
| 99 | # Include file(s) |
|---|
| 100 | include(tspsg.pri) |
|---|
| 101 | |
|---|
| 102 | # Installation and deployment |
|---|
| 103 | include(install.pri) |
|---|
