| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2011 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: tspsg.pro 157 2011-03-22 20:31:18Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/tspsg.pro $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | TEMPLATE = app |
|---|
| 24 | |
|---|
| 25 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 26 | |
|---|
| 27 | # Version information |
|---|
| 28 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 29 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 30 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 31 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2011 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 32 | |
|---|
| 33 | # Versioning |
|---|
| 34 | BUILD_VERSION_MAJOR = 0 |
|---|
| 35 | BUILD_VERSION_MINOR = 1 |
|---|
| 36 | BUILD_RELEASE = 4 |
|---|
| 37 | |
|---|
| 38 | # These are only defined on releases |
|---|
| 39 | #DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 40 | #DEFINES += BUILD_STATUS_TYPE=beta |
|---|
| 41 | #DEFINES += BUILD_STATUS_NUMBER=1 |
|---|
| 42 | |
|---|
| 43 | #REVISION = 145 |
|---|
| 44 | isEmpty(REVISION) { |
|---|
| 45 | REVISION = $$system(svnversion) |
|---|
| 46 | } |
|---|
| 47 | isEmpty(REVISION)|isEqual(REVISION,exported) { |
|---|
| 48 | REVISION = 0 |
|---|
| 49 | } else { |
|---|
| 50 | REVISION = $$replace(REVISION,":","") |
|---|
| 51 | REVISION = $$replace(REVISION,"M","") |
|---|
| 52 | } |
|---|
| 53 | SHORT_VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 54 | win32-msvc*|wincewm* { |
|---|
| 55 | VERSION = $$SHORT_VERSION |
|---|
| 56 | } else { |
|---|
| 57 | VERSION = $$sprintf("%1.%2",$$SHORT_VERSION,$$BUILD_RELEASE) |
|---|
| 58 | } |
|---|
| 59 | |
|---|
| 60 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 61 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 62 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 63 | BUILD_NUMBER=$$REVISION |
|---|
| 64 | |
|---|
| 65 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 66 | macx { |
|---|
| 67 | PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl |
|---|
| 68 | } else:symbian|maemo*|simulator { |
|---|
| 69 | # Nothing here |
|---|
| 70 | } else:unix { |
|---|
| 71 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 72 | } else { |
|---|
| 73 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 74 | } |
|---|
| 75 | !isEmpty(PRL) { |
|---|
| 76 | include($$join(PRL, "/")) |
|---|
| 77 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 78 | # We "embed" SVG icon support on static build |
|---|
| 79 | DEFINES += STATIC_BUILD |
|---|
| 80 | # !nosvg:QTPLUGIN += qsvgicon |
|---|
| 81 | } |
|---|
| 82 | } |
|---|
| 83 | |
|---|
| 84 | CONFIG(release, debug|release) { |
|---|
| 85 | OBJECTS_DIR = release |
|---|
| 86 | D = |
|---|
| 87 | } else { |
|---|
| 88 | OBJECTS_DIR = debug |
|---|
| 89 | DEFINES += DEBUG |
|---|
| 90 | # CONFIG += console |
|---|
| 91 | D = d |
|---|
| 92 | } |
|---|
| 93 | DESTDIR = bin |
|---|
| 94 | TARGET = tspsg$${D} |
|---|
| 95 | |
|---|
| 96 | # Saving all intermediate files to tmp directory. |
|---|
| 97 | MOC_DIR = tmp |
|---|
| 98 | RCC_DIR = tmp |
|---|
| 99 | UI_DIR = tmp |
|---|
| 100 | |
|---|
| 101 | # Include 3rd party libraries |
|---|
| 102 | !handheld { |
|---|
| 103 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 104 | } |
|---|
| 105 | |
|---|
| 106 | win32:LIBS += -lole32 |
|---|
| 107 | |
|---|
| 108 | # Include file(s) |
|---|
| 109 | include(tspsg.pri) |
|---|
| 110 | |
|---|
| 111 | # Installation and deployment rules |
|---|
| 112 | include(install.pri) |
|---|
