| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: tspsg.pro 87 2010-01-12 14:11:24Z laleppa $ |
|---|
| 7 | # $URL: https://tspsg.svn.sourceforge.net/svnroot/tspsg/trunk/tspsg.pro $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | QT += svg |
|---|
| 14 | |
|---|
| 15 | TEMPLATE = app |
|---|
| 16 | TARGET = tspsg |
|---|
| 17 | DEPENDPATH += . |
|---|
| 18 | INCLUDEPATH += . |
|---|
| 19 | |
|---|
| 20 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 21 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 22 | include($$join(PRL, "/")) |
|---|
| 23 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 24 | # We "embed" SVG and JPEG support on static build |
|---|
| 25 | QTPLUGIN += qjpeg qsvg |
|---|
| 26 | DEFINES += STATIC_BUILD |
|---|
| 27 | } |
|---|
| 28 | |
|---|
| 29 | CONFIG(release, debug|release) { |
|---|
| 30 | OBJECTS_DIR = release |
|---|
| 31 | DESTDIR = release |
|---|
| 32 | } else { |
|---|
| 33 | OBJECTS_DIR = debug |
|---|
| 34 | DESTDIR = debug |
|---|
| 35 | } |
|---|
| 36 | |
|---|
| 37 | # Saving all intermediate files to tmp directory. |
|---|
| 38 | MOC_DIR = ./tmp |
|---|
| 39 | RCC_DIR = ./tmp |
|---|
| 40 | UI_DIR = ./tmp |
|---|
| 41 | |
|---|
| 42 | #Include file(s) |
|---|
| 43 | include(tspsg.pri) |
|---|
| 44 | |
|---|
| 45 | # For *nix: |
|---|
| 46 | # - executable goes to $(INSTALL_ROOT)/bin |
|---|
| 47 | # - COPYING and README go to $(INSTALL_ROOT)/share/tspsg |
|---|
| 48 | # - translations go to $(INSTALL_ROOT)/share/tspsg/i18n |
|---|
| 49 | # - docs (none, yet) go to $(INSTALL_ROOT)/share/doc/tspsg |
|---|
| 50 | # Usually, $(INSTALL_ROOT) is /usr or /usr/local |
|---|
| 51 | unix { |
|---|
| 52 | target.path = /bin |
|---|
| 53 | share.path = /share/tspsg |
|---|
| 54 | share.files = COPYING README |
|---|
| 55 | i18n.path = /share/tspsg/i18n |
|---|
| 56 | i18n.files = i18n/languages.ini i18n/*.qm |
|---|
| 57 | docs.path = /share/doc/tspsg |
|---|
| 58 | # docs.files = docs/* |
|---|
| 59 | apps.path = /share/applications/ |
|---|
| 60 | apps.files = resources/tspsg.desktop |
|---|
| 61 | icon.path = /share/pixmaps |
|---|
| 62 | icon.files = resources/tspsg.png |
|---|
| 63 | INSTALLS += target i18n docs share icon apps |
|---|
| 64 | } |
|---|
| 65 | |
|---|
| 66 | # For win32: everything goes to $(INSTALL_ROOT)\tspsg and subfolders. |
|---|
| 67 | # Usually, $(INSTALL_ROOT) is "C:\Program Files" |
|---|
| 68 | win32 { |
|---|
| 69 | target.path = "\tspsg" |
|---|
| 70 | share.path = "\tspsg" |
|---|
| 71 | share.files = COPYING README |
|---|
| 72 | i18n.path = "\tspsg\i18n" |
|---|
| 73 | i18n.files = i18n\languages.ini i18n\*.qm |
|---|
| 74 | docs.path = "\tspsg\help" |
|---|
| 75 | # docs.files = docs\* |
|---|
| 76 | INSTALLS += target i18n docs share |
|---|
| 77 | } |
|---|
| 78 | |
|---|
| 79 | # TODO: MacOSX |
|---|
| 80 | |
|---|
| 81 | # For wince: we are deploying to \Storage Card\Program Files\tspsg. |
|---|
| 82 | wince { |
|---|
| 83 | deploy.path = "\Storage Card\Program Files\tspsg" |
|---|
| 84 | share.sources = COPYING README |
|---|
| 85 | share.path = "\Storage Card\Program Files\tspsg" |
|---|
| 86 | i18n.sources = i18n\languages.ini i18n\*.qm |
|---|
| 87 | i18n.path = "\Storage Card\Program Files\tspsg\i18n" |
|---|
| 88 | # docs.sources = docs\* |
|---|
| 89 | # docs.path = "\Storage Card\Program Files\tspsg\help" |
|---|
| 90 | DEPLOYMENT += deploy share i18n # docs |
|---|
| 91 | } |
|---|
| 92 | |
|---|
| 93 | #Windows resource file |
|---|
| 94 | win32:RC_FILE = resources/tspsg.rc |
|---|
