| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2010 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | # Common rules |
|---|
| 14 | l10n.files = l10n/*.qm |
|---|
| 15 | #share.files = |
|---|
| 16 | docs.files = COPYING README.txt |
|---|
| 17 | INSTALLS += target l10n share docs |
|---|
| 18 | |
|---|
| 19 | # For *nix: |
|---|
| 20 | # - executable goes to /usr/bin |
|---|
| 21 | # - COPYING and README go to /usr/share/TSPSG |
|---|
| 22 | # - translations go to /usr/share/TSPSG/l10n |
|---|
| 23 | # - docs go to /usr/share/doc/TSPSG-x.x.x |
|---|
| 24 | unix:!macx:!symbian { |
|---|
| 25 | PREFIX = /usr |
|---|
| 26 | CONFIG(release, debug|release) { |
|---|
| 27 | DEFINES += PATH_L10N=\\\"$$PREFIX/share/TSPSG/l10n\\\" |
|---|
| 28 | DEFINES += PATH_DOCS=\\\"$$PREFIX/share/TSPSG/docs\\\" |
|---|
| 29 | } |
|---|
| 30 | |
|---|
| 31 | target.path = $$PREFIX/bin |
|---|
| 32 | share.path = $$PREFIX/share/TSPSG |
|---|
| 33 | l10n.path = $$PREFIX/share/TSPSG/l10n |
|---|
| 34 | docs.path = $$PREFIX/share/doc/TSPSG-$$VERSION |
|---|
| 35 | apps.files = resources/tspsg.desktop |
|---|
| 36 | apps.path = $$PREFIX/share/applications/ |
|---|
| 37 | icon.files = resources/tspsg.png |
|---|
| 38 | icon.path = $$PREFIX/share/pixmaps |
|---|
| 39 | INSTALLS += apps icon |
|---|
| 40 | } |
|---|
| 41 | |
|---|
| 42 | # TODO: MacOSX |
|---|
| 43 | macx { |
|---|
| 44 | } |
|---|
| 45 | |
|---|
| 46 | # For win32: everything goes to "%PROGRAMFILES%\TSPSG" and subfolders. |
|---|
| 47 | win32 { |
|---|
| 48 | PREFIX = "$$(PROGRAMFILES)" |
|---|
| 49 | |
|---|
| 50 | share.files = $$[QT_INSTALL_BINS]/QtCore$${D}4.dll \ |
|---|
| 51 | $$[QT_INSTALL_BINS]/QtGui$${D}4.dll |
|---|
| 52 | !nosvg { |
|---|
| 53 | share.files += $$[QT_INSTALL_BINS]/QtSvg$${D}4.dll |
|---|
| 54 | } |
|---|
| 55 | l10n.files += $$[QT_INSTALL_TRANSLATIONS]/*.qm |
|---|
| 56 | win32-g++ { |
|---|
| 57 | share.files += $$[QT_INSTALL_BINS]/mingwm10.dll \ |
|---|
| 58 | $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll |
|---|
| 59 | } |
|---|
| 60 | imageformats.files = $$[QT_INSTALL_PLUGINS]/imageformats/qjpeg$${D}4.dll \ |
|---|
| 61 | $$[QT_INSTALL_PLUGINS]/imageformats/qtiff$${D}4.dll |
|---|
| 62 | imageformats.path = $$PREFIX/TSPSG/imageformats |
|---|
| 63 | INSTALLS += imageformats |
|---|
| 64 | } |
|---|
| 65 | |
|---|
| 66 | # For wince: we are deploying to \Program Files\TSPSG. |
|---|
| 67 | wince* { |
|---|
| 68 | PREFIX = "\Program Files" |
|---|
| 69 | share.sources = $$share.files |
|---|
| 70 | l10n.sources = $$l10n.files \ |
|---|
| 71 | $$[QT_INSTALL_TRANSLATIONS]/*.qm |
|---|
| 72 | docs.sources = $$docs.files |
|---|
| 73 | |
|---|
| 74 | DEPLOYMENT += target share l10n docs |
|---|
| 75 | # DEPLOYMENT_PLUGIN += qjpeg qtiff |
|---|
| 76 | } |
|---|
| 77 | |
|---|
| 78 | # win32 and wince common |
|---|
| 79 | win* { |
|---|
| 80 | target.path = $$PREFIX/TSPSG |
|---|
| 81 | share.path = $$PREFIX/TSPSG |
|---|
| 82 | l10n.path = $$PREFIX/TSPSG/l10n |
|---|
| 83 | docs.path = $$PREFIX/TSPSG |
|---|
| 84 | |
|---|
| 85 | RC_FILE = resources/tspsg.rc |
|---|
| 86 | } |
|---|
| 87 | |
|---|
| 88 | # Symbian |
|---|
| 89 | symbian { |
|---|
| 90 | # qmake for Symbian (as of Qt 4.6.2) has a bug: file masks doesn't work, so we need to specify all files manually |
|---|
| 91 | share.sources = $$share.files |
|---|
| 92 | l10n.sources = $$[QT_INSTALL_TRANSLATIONS]/qt_ru.qm \ |
|---|
| 93 | $$[QT_INSTALL_TRANSLATIONS]/qt_uk.qm \ |
|---|
| 94 | l10n/tspsg_en.qm l10n/tspsg_ru.qm l10n/tspsg_uk.qm |
|---|
| 95 | l10n.path = l10n |
|---|
| 96 | docs.sources = $$docs.files |
|---|
| 97 | docs.pkg_prerules = \ |
|---|
| 98 | "\"README.txt\" - \"\", FILETEXT, TEXTCONTINUE" \ |
|---|
| 99 | "\"COPYING\" - \"\", FILETEXT, TEXTEXIT" |
|---|
| 100 | DEPLOYMENT += share l10n docs |
|---|
| 101 | # DEPLOYMENT_PLUGIN += qjpeg qtiff |
|---|
| 102 | |
|---|
| 103 | ICON = resources/tspsg.svg |
|---|
| 104 | |
|---|
| 105 | appinfo = \ |
|---|
| 106 | "$$LITERAL_HASH{\"TSPSG\"},(0xEb9dce0e),$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR,$$BUILD_RELEASE" |
|---|
| 107 | vendorinfo = \ |
|---|
| 108 | "%{\"l-homes.org\"}" \ |
|---|
| 109 | ":\"l-homes.org\"" |
|---|
| 110 | default_deployment.pkg_prerules = appinfo vendorinfo |
|---|
| 111 | DEPLOYMENT.installer_header = "$${LITERAL_HASH}{\"TSPSG Installer\"},(0xA000D7CE),1,0,0" |
|---|
| 112 | } |
|---|
