| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2011 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | TEMPLATE = app |
|---|
| 24 | |
|---|
| 25 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 26 | |
|---|
| 27 | # Version information |
|---|
| 28 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 29 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 30 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 31 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2011 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 32 | |
|---|
| 33 | # Versioning |
|---|
| 34 | BUILD_VERSION_MAJOR = 0 |
|---|
| 35 | BUILD_VERSION_MINOR = 1 |
|---|
| 36 | BUILD_RELEASE = 4 |
|---|
| 37 | |
|---|
| 38 | # These are only defined on releases |
|---|
| 39 | DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 40 | DEFINES += BUILD_STATUS_TYPE=beta |
|---|
| 41 | DEFINES += BUILD_STATUS_NUMBER=2 |
|---|
| 42 | |
|---|
| 43 | REVISION = 170 |
|---|
| 44 | isEmpty(REVISION) { |
|---|
| 45 | REVISION = $$system(svnversion) |
|---|
| 46 | } |
|---|
| 47 | isEmpty(REVISION)|isEqual(REVISION,exported) { |
|---|
| 48 | REVISION = 0 |
|---|
| 49 | } else { |
|---|
| 50 | REVISION = $$replace(REVISION,":","") |
|---|
| 51 | REVISION = $$replace(REVISION,"M","") |
|---|
| 52 | } |
|---|
| 53 | SHORT_VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 54 | win32-msvc*|wincewm* { |
|---|
| 55 | VERSION = $$SHORT_VERSION |
|---|
| 56 | } else { |
|---|
| 57 | VERSION = $$sprintf("%1.%2",$$SHORT_VERSION,$$BUILD_RELEASE) |
|---|
| 58 | } |
|---|
| 59 | |
|---|
| 60 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 61 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 62 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 63 | BUILD_NUMBER=$$REVISION |
|---|
| 64 | |
|---|
| 65 | blackberry { |
|---|
| 66 | TARGET = tspsg |
|---|
| 67 | } else { |
|---|
| 68 | CONFIG(release, debug|release) { |
|---|
| 69 | OBJECTS_DIR = release |
|---|
| 70 | D = |
|---|
| 71 | } else { |
|---|
| 72 | OBJECTS_DIR = debug |
|---|
| 73 | DEFINES += DEBUG |
|---|
| 74 | # CONFIG += console |
|---|
| 75 | D = d |
|---|
| 76 | } |
|---|
| 77 | DESTDIR = bin |
|---|
| 78 | TARGET = tspsg$${D} |
|---|
| 79 | } |
|---|
| 80 | |
|---|
| 81 | # Saving all intermediate files to tmp directory. |
|---|
| 82 | MOC_DIR = tmp |
|---|
| 83 | RCC_DIR = tmp |
|---|
| 84 | UI_DIR = tmp |
|---|
| 85 | |
|---|
| 86 | # Include 3rd party libraries |
|---|
| 87 | !handheld { |
|---|
| 88 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 89 | } |
|---|
| 90 | |
|---|
| 91 | win32:LIBS += -lole32 |
|---|
| 92 | |
|---|
| 93 | # Include file(s) |
|---|
| 94 | include(tspsg.pri) |
|---|
| 95 | |
|---|
| 96 | # Installation and deployment rules |
|---|
| 97 | include(install.pri) |
|---|
