| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2012 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | greaterThan(QT_MAJOR_VERSION, 4) { |
|---|
| 20 | QT += printsupport concurrent |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | wincewm*|symbian|maemo*|simulator { |
|---|
| 24 | CONFIG += handheld |
|---|
| 25 | } |
|---|
| 26 | |
|---|
| 27 | TEMPLATE = app |
|---|
| 28 | |
|---|
| 29 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 30 | |
|---|
| 31 | # Version information |
|---|
| 32 | QMAKE_TARGET_COMPANY = Oleksii Serdiuk |
|---|
| 33 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 34 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 35 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2012 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 36 | |
|---|
| 37 | # Version detection |
|---|
| 38 | include(version.pri) |
|---|
| 39 | |
|---|
| 40 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 41 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 42 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 43 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 44 | |
|---|
| 45 | CONFIG(release, debug|release) { |
|---|
| 46 | OBJECTS_DIR = release |
|---|
| 47 | D = |
|---|
| 48 | } else { |
|---|
| 49 | OBJECTS_DIR = debug |
|---|
| 50 | DEFINES += DEBUG |
|---|
| 51 | # CONFIG += console |
|---|
| 52 | D = d |
|---|
| 53 | } |
|---|
| 54 | DESTDIR = bin |
|---|
| 55 | TARGET = tspsg$${D} |
|---|
| 56 | |
|---|
| 57 | # Saving all intermediate files to tmp directory. |
|---|
| 58 | MOC_DIR = tmp |
|---|
| 59 | RCC_DIR = tmp |
|---|
| 60 | UI_DIR = tmp |
|---|
| 61 | |
|---|
| 62 | # We need to generate translations before building. |
|---|
| 63 | # Either way, resource files won't compile. |
|---|
| 64 | translations.name = Translations |
|---|
| 65 | translations.input = TRANSLATIONS |
|---|
| 66 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 67 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 68 | translations.CONFIG = no_link |
|---|
| 69 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 70 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 71 | |
|---|
| 72 | # Include 3rd party libraries |
|---|
| 73 | !handheld { |
|---|
| 74 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 75 | } |
|---|
| 76 | |
|---|
| 77 | win32:LIBS += -lole32 |
|---|
| 78 | |
|---|
| 79 | # Source |
|---|
| 80 | include(tspsg.pri) |
|---|
| 81 | |
|---|
| 82 | # Help |
|---|
| 83 | include(help/help.pri) |
|---|
| 84 | |
|---|
| 85 | # Code Documentation |
|---|
| 86 | include(doc/doc.pri) |
|---|
| 87 | |
|---|
| 88 | # Installation and deployment rules |
|---|
| 89 | include(install.pri) |
|---|
