| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2014 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | greaterThan(QT_MAJOR_VERSION, 4) { |
|---|
| 20 | QT += printsupport concurrent |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 24 | CONFIG += handheld |
|---|
| 25 | } |
|---|
| 26 | blackberry { |
|---|
| 27 | # DEFINES += QT_NO_SHORTCUT |
|---|
| 28 | DEFINES += QT_NO_PRINTDIALOG |
|---|
| 29 | DEFINES += QT_NO_PRINTPREVIEWDIALOG |
|---|
| 30 | |
|---|
| 31 | QT += xml declarative |
|---|
| 32 | LIBS += -lbb -lbbcascadespickers |
|---|
| 33 | } |
|---|
| 34 | |
|---|
| 35 | TEMPLATE = app |
|---|
| 36 | |
|---|
| 37 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 38 | |
|---|
| 39 | # Version information |
|---|
| 40 | QMAKE_TARGET_COMPANY = Oleksii Serdiuk |
|---|
| 41 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 42 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 43 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2014 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 44 | |
|---|
| 45 | # Version detection |
|---|
| 46 | include(version.pri) |
|---|
| 47 | |
|---|
| 48 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 49 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 50 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 51 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 52 | |
|---|
| 53 | blackberry { |
|---|
| 54 | D = |
|---|
| 55 | } else { |
|---|
| 56 | !debug_and_release|build_pass { |
|---|
| 57 | CONFIG(debug, debug|release) { |
|---|
| 58 | OBJECTS_DIR = debug |
|---|
| 59 | DEFINES += DEBUG |
|---|
| 60 | # CONFIG += console |
|---|
| 61 | D = d |
|---|
| 62 | } else { |
|---|
| 63 | OBJECTS_DIR = release |
|---|
| 64 | D = |
|---|
| 65 | } |
|---|
| 66 | } |
|---|
| 67 | DESTDIR = bin |
|---|
| 68 | } |
|---|
| 69 | TARGET = tspsg$${D} |
|---|
| 70 | |
|---|
| 71 | # Saving all intermediate files to tmp directory. |
|---|
| 72 | MOC_DIR = tmp |
|---|
| 73 | RCC_DIR = tmp |
|---|
| 74 | UI_DIR = tmp |
|---|
| 75 | |
|---|
| 76 | # We need to generate translations before building. |
|---|
| 77 | # Either way, resource files won't compile. |
|---|
| 78 | translations.name = Translations |
|---|
| 79 | translations.input = TRANSLATIONS |
|---|
| 80 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 81 | freebsd-* { |
|---|
| 82 | translations.commands = $$[QT_INSTALL_BINS]/lrelease-qt$${QT_MAJOR_VERSION} ${QMAKE_FILE_IN} |
|---|
| 83 | } else { |
|---|
| 84 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 85 | } |
|---|
| 86 | translations.CONFIG = no_link |
|---|
| 87 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 88 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 89 | |
|---|
| 90 | # Include 3rd party libraries |
|---|
| 91 | !handheld { |
|---|
| 92 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 93 | |
|---|
| 94 | unix:LIBS += -lX11 |
|---|
| 95 | } |
|---|
| 96 | |
|---|
| 97 | win32:LIBS += -lole32 |
|---|
| 98 | |
|---|
| 99 | # Source |
|---|
| 100 | include(tspsg.pri) |
|---|
| 101 | |
|---|
| 102 | # Help |
|---|
| 103 | include(help/help.pri) |
|---|
| 104 | |
|---|
| 105 | # Code Documentation |
|---|
| 106 | include(doc/doc.pri) |
|---|
| 107 | |
|---|
| 108 | # Installation and deployment rules |
|---|
| 109 | include(install.pri) |
|---|
