| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | greaterThan(QT_MAJOR_VERSION, 4) { |
|---|
| 20 | QT += printsupport concurrent |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | wincewm*|symbian|maemo*|simulator { |
|---|
| 24 | CONFIG += handheld |
|---|
| 25 | } |
|---|
| 26 | |
|---|
| 27 | TEMPLATE = app |
|---|
| 28 | |
|---|
| 29 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 30 | |
|---|
| 31 | # Version information |
|---|
| 32 | QMAKE_TARGET_COMPANY = Oleksii Serdiuk |
|---|
| 33 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 34 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 35 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 36 | |
|---|
| 37 | # Version detection |
|---|
| 38 | include(version.pri) |
|---|
| 39 | |
|---|
| 40 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 41 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 42 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 43 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 44 | |
|---|
| 45 | !debug_and_release|build_pass { |
|---|
| 46 | CONFIG(debug, debug|release) { |
|---|
| 47 | OBJECTS_DIR = debug |
|---|
| 48 | DEFINES += DEBUG |
|---|
| 49 | # CONFIG += console |
|---|
| 50 | D = d |
|---|
| 51 | } else { |
|---|
| 52 | OBJECTS_DIR = release |
|---|
| 53 | D = |
|---|
| 54 | } |
|---|
| 55 | } |
|---|
| 56 | DESTDIR = bin |
|---|
| 57 | TARGET = tspsg$${D} |
|---|
| 58 | |
|---|
| 59 | # Saving all intermediate files to tmp directory. |
|---|
| 60 | MOC_DIR = tmp |
|---|
| 61 | RCC_DIR = tmp |
|---|
| 62 | UI_DIR = tmp |
|---|
| 63 | |
|---|
| 64 | # We need to generate translations before building. |
|---|
| 65 | # Either way, resource files won't compile. |
|---|
| 66 | translations.name = Translations |
|---|
| 67 | translations.input = TRANSLATIONS |
|---|
| 68 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 69 | freebsd-* { |
|---|
| 70 | translations.commands = $$[QT_INSTALL_BINS]/lrelease-qt$${QT_MAJOR_VERSION} ${QMAKE_FILE_IN} |
|---|
| 71 | } else { |
|---|
| 72 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 73 | } |
|---|
| 74 | translations.CONFIG = no_link |
|---|
| 75 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 76 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 77 | |
|---|
| 78 | # Include 3rd party libraries |
|---|
| 79 | !handheld { |
|---|
| 80 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 81 | } |
|---|
| 82 | |
|---|
| 83 | win32:LIBS += -lole32 |
|---|
| 84 | |
|---|
| 85 | # Source |
|---|
| 86 | include(tspsg.pri) |
|---|
| 87 | |
|---|
| 88 | # Help |
|---|
| 89 | include(help/help.pri) |
|---|
| 90 | |
|---|
| 91 | # Code Documentation |
|---|
| 92 | include(doc/doc.pri) |
|---|
| 93 | |
|---|
| 94 | # Installation and deployment rules |
|---|
| 95 | include(install.pri) |
|---|
