| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2009 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | TEMPLATE = app |
|---|
| 14 | TARGET = tspsg |
|---|
| 15 | DEPENDPATH += . |
|---|
| 16 | INCLUDEPATH += . |
|---|
| 17 | |
|---|
| 18 | CONFIG(release, debug|release) { |
|---|
| 19 | OBJECTS_DIR = release |
|---|
| 20 | DESTDIR = release |
|---|
| 21 | } else { |
|---|
| 22 | OBJECTS_DIR = debug |
|---|
| 23 | DESTDIR = debug |
|---|
| 24 | } |
|---|
| 25 | |
|---|
| 26 | # Saving all intermediate files to tmp directory. |
|---|
| 27 | MOC_DIR = ./tmp |
|---|
| 28 | RCC_DIR = ./tmp |
|---|
| 29 | UI_DIR = ./tmp |
|---|
| 30 | |
|---|
| 31 | #Include file(s) |
|---|
| 32 | include(tspsg.pri) |
|---|
| 33 | |
|---|
| 34 | # For *nix: |
|---|
| 35 | # - executable goes to $(INSTALL_ROOT)/bin |
|---|
| 36 | # - COPYING and README go to $(INSTALL_ROOT)/share/tspsg |
|---|
| 37 | # - translations go to $(INSTALL_ROOT)/share/tspsg/i18n |
|---|
| 38 | # - docs (none, yet) go to $(INSTALL_ROOT)/share/doc/tspsg |
|---|
| 39 | # Usually, $(INSTALL_ROOT) is /usr or /usr/local |
|---|
| 40 | unix { |
|---|
| 41 | target.path = /bin |
|---|
| 42 | share.path = /share/tspsg |
|---|
| 43 | share.files = COPYING README |
|---|
| 44 | i18n.path = /share/tspsg/i18n |
|---|
| 45 | i18n.files = i18n/languages.ini i18n/*.qm |
|---|
| 46 | docs.path = /share/doc/tspsg |
|---|
| 47 | # docs.files = docs/* |
|---|
| 48 | INSTALLS += target i18n docs share |
|---|
| 49 | } |
|---|
| 50 | |
|---|
| 51 | # For win32: everything goes to $(INSTALL_ROOT)\tspsg and subfolders. |
|---|
| 52 | # Usually, $(INSTALL_ROOT) is "C:\Program Files" |
|---|
| 53 | win32 { |
|---|
| 54 | target.path = "\tspsg" |
|---|
| 55 | share.path = "\tspsg" |
|---|
| 56 | share.files = COPYING README |
|---|
| 57 | i18n.path = "\tspsg\i18n" |
|---|
| 58 | i18n.files = i18n\languages.ini i18n\*.qm |
|---|
| 59 | docs.path = "\tspsg\help" |
|---|
| 60 | # docs.files = docs\* |
|---|
| 61 | INSTALLS += target i18n docs share |
|---|
| 62 | } |
|---|
| 63 | |
|---|
| 64 | # TODO: MacOSX |
|---|
| 65 | |
|---|
| 66 | # For wince: we are deploying to \Storage Card\Program Files\tspsg. |
|---|
| 67 | wince { |
|---|
| 68 | deploy.path = "\Storage Card\Program Files\tspsg" |
|---|
| 69 | share.sources = COPYING README |
|---|
| 70 | share.path = "\Storage Card\Program Files\tspsg" |
|---|
| 71 | i18n.sources = i18n\languages.ini i18n\*.qm |
|---|
| 72 | i18n.path = "\Storage Card\Program Files\tspsg\i18n" |
|---|
| 73 | # docs.sources = docs\* |
|---|
| 74 | # docs.path = "\Storage Card\Program Files\tspsg\help" |
|---|
| 75 | DEPLOYMENT += deploy share i18n # docs |
|---|
| 76 | } |
|---|
| 77 | |
|---|
| 78 | #Windows resource file |
|---|
| 79 | win32:RC_FILE = resources/tspsg.rc |
|---|
