| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2011 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | TEMPLATE = app |
|---|
| 24 | |
|---|
| 25 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 26 | |
|---|
| 27 | # Version information |
|---|
| 28 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 29 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 30 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 31 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2011 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 32 | |
|---|
| 33 | # Version detection |
|---|
| 34 | include(version.pri) |
|---|
| 35 | |
|---|
| 36 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 37 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 38 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 39 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 40 | |
|---|
| 41 | CONFIG(release, debug|release) { |
|---|
| 42 | OBJECTS_DIR = release |
|---|
| 43 | D = |
|---|
| 44 | } else { |
|---|
| 45 | OBJECTS_DIR = debug |
|---|
| 46 | DEFINES += DEBUG |
|---|
| 47 | # CONFIG += console |
|---|
| 48 | D = d |
|---|
| 49 | } |
|---|
| 50 | DESTDIR = bin |
|---|
| 51 | TARGET = tspsg$${D} |
|---|
| 52 | |
|---|
| 53 | # Saving all intermediate files to tmp directory. |
|---|
| 54 | MOC_DIR = tmp |
|---|
| 55 | RCC_DIR = tmp |
|---|
| 56 | UI_DIR = tmp |
|---|
| 57 | |
|---|
| 58 | # We need to generate translations before building. |
|---|
| 59 | # Either way, resource files won't compile. |
|---|
| 60 | translations.name = Translations |
|---|
| 61 | translations.input = TRANSLATIONS |
|---|
| 62 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 63 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 64 | translations.CONFIG = no_link |
|---|
| 65 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 66 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 67 | |
|---|
| 68 | # Include 3rd party libraries |
|---|
| 69 | !handheld { |
|---|
| 70 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 71 | } |
|---|
| 72 | |
|---|
| 73 | win32:LIBS += -lole32 |
|---|
| 74 | |
|---|
| 75 | # Include file(s) |
|---|
| 76 | include(tspsg.pri) |
|---|
| 77 | |
|---|
| 78 | # Installation and deployment rules |
|---|
| 79 | include(install.pri) |
|---|
