| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2011 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | TEMPLATE = app |
|---|
| 24 | |
|---|
| 25 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 26 | |
|---|
| 27 | # Version information |
|---|
| 28 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 29 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 30 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 31 | QMAKE_TARGET_COPYRIGHT = Copyright © 200-20110 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 32 | |
|---|
| 33 | # Versioning |
|---|
| 34 | BUILD_VERSION_MAJOR = 0 |
|---|
| 35 | BUILD_VERSION_MINOR = 1 |
|---|
| 36 | BUILD_RELEASE = 4 |
|---|
| 37 | |
|---|
| 38 | # These are only defined on releases |
|---|
| 39 | #DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 40 | #DEFINES += BUILD_STATUS_TYPE=beta |
|---|
| 41 | #DEFINES += BUILD_STATUS_NUMBER=1 |
|---|
| 42 | |
|---|
| 43 | #REVISION = 145 |
|---|
| 44 | REVISION = $$system(svnversion) |
|---|
| 45 | isEmpty(REVISION)|isEqual(REVISION,exported) { |
|---|
| 46 | REVISION = 0 |
|---|
| 47 | } else { |
|---|
| 48 | REVISION = $$replace(REVISION,":","") |
|---|
| 49 | REVISION = $$replace(REVISION,"M","") |
|---|
| 50 | } |
|---|
| 51 | SHORT_VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 52 | win32-msvc*|wincewm* { |
|---|
| 53 | VERSION = $$SHORT_VERSION |
|---|
| 54 | } else { |
|---|
| 55 | VERSION = $$sprintf("%1.%2",$$SHORT_VERSION,$$BUILD_RELEASE) |
|---|
| 56 | } |
|---|
| 57 | |
|---|
| 58 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 59 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 60 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 61 | BUILD_NUMBER=$$REVISION |
|---|
| 62 | |
|---|
| 63 | # A hack to determine whether we have static or dynamic Qt build |
|---|
| 64 | macx { |
|---|
| 65 | PRL = $$[QT_INSTALL_LIBS] QtCore.framework QtCore.prl |
|---|
| 66 | } else:symbian { |
|---|
| 67 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 68 | } else:unix { |
|---|
| 69 | PRL = $$[QT_INSTALL_LIBS] libQtCore.prl |
|---|
| 70 | } else { |
|---|
| 71 | PRL = $$[QT_INSTALL_LIBS] QtCore.prl |
|---|
| 72 | } |
|---|
| 73 | include($$join(PRL, "/")) |
|---|
| 74 | contains(QMAKE_PRL_CONFIG, static) { |
|---|
| 75 | # We "embed" SVG icon support on static build |
|---|
| 76 | DEFINES += STATIC_BUILD |
|---|
| 77 | # !nosvg:QTPLUGIN += qsvgicon |
|---|
| 78 | } |
|---|
| 79 | |
|---|
| 80 | CONFIG(release, debug|release) { |
|---|
| 81 | OBJECTS_DIR = release |
|---|
| 82 | D = |
|---|
| 83 | } else { |
|---|
| 84 | OBJECTS_DIR = debug |
|---|
| 85 | DEFINES += DEBUG |
|---|
| 86 | # CONFIG += console |
|---|
| 87 | D = d |
|---|
| 88 | } |
|---|
| 89 | DESTDIR = bin |
|---|
| 90 | TARGET = tspsg$${D} |
|---|
| 91 | |
|---|
| 92 | # Saving all intermediate files to tmp directory. |
|---|
| 93 | MOC_DIR = tmp |
|---|
| 94 | RCC_DIR = tmp |
|---|
| 95 | UI_DIR = tmp |
|---|
| 96 | |
|---|
| 97 | # Include 3rd party libraries |
|---|
| 98 | !handheld { |
|---|
| 99 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 100 | } |
|---|
| 101 | |
|---|
| 102 | win32:LIBS += -lole32 |
|---|
| 103 | |
|---|
| 104 | # Include file(s) |
|---|
| 105 | include(tspsg.pri) |
|---|
| 106 | |
|---|
| 107 | # Installation and deployment |
|---|
| 108 | include(install.pri) |
|---|
