| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2011 Lёppa <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id$ |
|---|
| 7 | # $URL$ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 20 | CONFIG += handheld |
|---|
| 21 | } |
|---|
| 22 | blackberry { |
|---|
| 23 | # DEFINES += QT_NO_SHORTCUT |
|---|
| 24 | DEFINES += QT_NO_PRINTDIALOG |
|---|
| 25 | DEFINES += QT_NO_PRINTPREVIEWDIALOG |
|---|
| 26 | |
|---|
| 27 | QT += xml declarative |
|---|
| 28 | LIBS += -lbb -lbbcascadespickers |
|---|
| 29 | } |
|---|
| 30 | |
|---|
| 31 | TEMPLATE = app |
|---|
| 32 | |
|---|
| 33 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 34 | |
|---|
| 35 | # Version information |
|---|
| 36 | QMAKE_TARGET_COMPANY = Oleksii "Lёppa" Serdiuk |
|---|
| 37 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 38 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 39 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2011 Oleksii "Lёppa" Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 40 | |
|---|
| 41 | # Versioning |
|---|
| 42 | BUILD_VERSION_MAJOR = 0 |
|---|
| 43 | BUILD_VERSION_MINOR = 1 |
|---|
| 44 | BUILD_RELEASE = 4 |
|---|
| 45 | |
|---|
| 46 | # These are only defined on releases |
|---|
| 47 | DEFINES += TSPSG_RELEASE_BUILD |
|---|
| 48 | DEFINES += BUILD_STATUS_TYPE=beta |
|---|
| 49 | DEFINES += BUILD_STATUS_NUMBER=2 |
|---|
| 50 | |
|---|
| 51 | REVISION = 170 |
|---|
| 52 | isEmpty(REVISION) { |
|---|
| 53 | REVISION = $$system(svnversion) |
|---|
| 54 | } |
|---|
| 55 | isEmpty(REVISION)|isEqual(REVISION,exported) { |
|---|
| 56 | REVISION = 0 |
|---|
| 57 | } else { |
|---|
| 58 | REVISION = $$replace(REVISION,":","") |
|---|
| 59 | REVISION = $$replace(REVISION,"M","") |
|---|
| 60 | } |
|---|
| 61 | SHORT_VERSION = $$sprintf("%1.%2",$$BUILD_VERSION_MAJOR,$$BUILD_VERSION_MINOR) |
|---|
| 62 | win32-msvc*|wincewm* { |
|---|
| 63 | VERSION = $$SHORT_VERSION |
|---|
| 64 | } else { |
|---|
| 65 | VERSION = $$sprintf("%1.%2",$$SHORT_VERSION,$$BUILD_RELEASE) |
|---|
| 66 | } |
|---|
| 67 | |
|---|
| 68 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 69 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 70 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 71 | BUILD_NUMBER=$$REVISION |
|---|
| 72 | |
|---|
| 73 | blackberry { |
|---|
| 74 | TARGET = tspsg |
|---|
| 75 | } else { |
|---|
| 76 | CONFIG(release, debug|release) { |
|---|
| 77 | OBJECTS_DIR = release |
|---|
| 78 | D = |
|---|
| 79 | } else { |
|---|
| 80 | OBJECTS_DIR = debug |
|---|
| 81 | DEFINES += DEBUG |
|---|
| 82 | # CONFIG += console |
|---|
| 83 | D = d |
|---|
| 84 | } |
|---|
| 85 | DESTDIR = bin |
|---|
| 86 | TARGET = tspsg$${D} |
|---|
| 87 | } |
|---|
| 88 | |
|---|
| 89 | # Saving all intermediate files to tmp directory. |
|---|
| 90 | MOC_DIR = tmp |
|---|
| 91 | RCC_DIR = tmp |
|---|
| 92 | UI_DIR = tmp |
|---|
| 93 | |
|---|
| 94 | # Include 3rd party libraries |
|---|
| 95 | !handheld { |
|---|
| 96 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 97 | } |
|---|
| 98 | |
|---|
| 99 | win32:LIBS += -lole32 |
|---|
| 100 | |
|---|
| 101 | # Include file(s) |
|---|
| 102 | include(tspsg.pri) |
|---|
| 103 | |
|---|
| 104 | # Installation and deployment rules |
|---|
| 105 | include(install.pri) |
|---|
