| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | greaterThan(QT_MAJOR_VERSION, 4) { |
|---|
| 20 | QT += printsupport concurrent |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 24 | CONFIG += handheld |
|---|
| 25 | } |
|---|
| 26 | |
|---|
| 27 | TEMPLATE = app |
|---|
| 28 | |
|---|
| 29 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 30 | |
|---|
| 31 | # Version information |
|---|
| 32 | QMAKE_TARGET_COMPANY = Oleksii Serdiuk |
|---|
| 33 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 34 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 35 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 36 | |
|---|
| 37 | # Version detection |
|---|
| 38 | include(version.pri) |
|---|
| 39 | |
|---|
| 40 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 41 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 42 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 43 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 44 | |
|---|
| 45 | blackberry { |
|---|
| 46 | TARGET = tspsg |
|---|
| 47 | } else { |
|---|
| 48 | !debug_and_release|build_pass { |
|---|
| 49 | CONFIG(debug, debug|release) { |
|---|
| 50 | OBJECTS_DIR = debug |
|---|
| 51 | DEFINES += DEBUG |
|---|
| 52 | # CONFIG += console |
|---|
| 53 | D = d |
|---|
| 54 | } else { |
|---|
| 55 | OBJECTS_DIR = release |
|---|
| 56 | D = |
|---|
| 57 | } |
|---|
| 58 | } |
|---|
| 59 | } |
|---|
| 60 | |
|---|
| 61 | # Saving all intermediate files to tmp directory. |
|---|
| 62 | MOC_DIR = tmp |
|---|
| 63 | RCC_DIR = tmp |
|---|
| 64 | UI_DIR = tmp |
|---|
| 65 | |
|---|
| 66 | # We need to generate translations before building. |
|---|
| 67 | # Either way, resource files won't compile. |
|---|
| 68 | translations.name = Translations |
|---|
| 69 | translations.input = TRANSLATIONS |
|---|
| 70 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 71 | freebsd-* { |
|---|
| 72 | translations.commands = $$[QT_INSTALL_BINS]/lrelease-qt$${QT_MAJOR_VERSION} ${QMAKE_FILE_IN} |
|---|
| 73 | } else { |
|---|
| 74 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 75 | } |
|---|
| 76 | translations.CONFIG = no_link |
|---|
| 77 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 78 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 79 | |
|---|
| 80 | # Include 3rd party libraries |
|---|
| 81 | !handheld { |
|---|
| 82 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 83 | } |
|---|
| 84 | |
|---|
| 85 | win32:LIBS += -lole32 |
|---|
| 86 | |
|---|
| 87 | # Source |
|---|
| 88 | include(tspsg.pri) |
|---|
| 89 | |
|---|
| 90 | # Help |
|---|
| 91 | include(help/help.pri) |
|---|
| 92 | |
|---|
| 93 | # Code Documentation |
|---|
| 94 | include(doc/doc.pri) |
|---|
| 95 | |
|---|
| 96 | # Installation and deployment rules |
|---|
| 97 | include(install.pri) |
|---|
