| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | greaterThan(QT_MAJOR_VERSION, 4) { |
|---|
| 20 | QT += printsupport concurrent |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 24 | CONFIG += handheld |
|---|
| 25 | } |
|---|
| 26 | blackberry { |
|---|
| 27 | # DEFINES += QT_NO_SHORTCUT |
|---|
| 28 | DEFINES += QT_NO_PRINTDIALOG |
|---|
| 29 | DEFINES += QT_NO_PRINTPREVIEWDIALOG |
|---|
| 30 | } |
|---|
| 31 | |
|---|
| 32 | TEMPLATE = app |
|---|
| 33 | |
|---|
| 34 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 35 | |
|---|
| 36 | # Version information |
|---|
| 37 | QMAKE_TARGET_COMPANY = Oleksii Serdiuk |
|---|
| 38 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 39 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 40 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 41 | |
|---|
| 42 | # Version detection |
|---|
| 43 | include(version.pri) |
|---|
| 44 | |
|---|
| 45 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 46 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 47 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 48 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 49 | |
|---|
| 50 | blackberry { |
|---|
| 51 | TARGET = tspsg |
|---|
| 52 | } else { |
|---|
| 53 | !debug_and_release|build_pass { |
|---|
| 54 | CONFIG(debug, debug|release) { |
|---|
| 55 | OBJECTS_DIR = debug |
|---|
| 56 | DEFINES += DEBUG |
|---|
| 57 | # CONFIG += console |
|---|
| 58 | D = d |
|---|
| 59 | } else { |
|---|
| 60 | OBJECTS_DIR = release |
|---|
| 61 | D = |
|---|
| 62 | } |
|---|
| 63 | } |
|---|
| 64 | } |
|---|
| 65 | |
|---|
| 66 | # Saving all intermediate files to tmp directory. |
|---|
| 67 | MOC_DIR = tmp |
|---|
| 68 | RCC_DIR = tmp |
|---|
| 69 | UI_DIR = tmp |
|---|
| 70 | |
|---|
| 71 | # We need to generate translations before building. |
|---|
| 72 | # Either way, resource files won't compile. |
|---|
| 73 | translations.name = Translations |
|---|
| 74 | translations.input = TRANSLATIONS |
|---|
| 75 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 76 | freebsd-* { |
|---|
| 77 | translations.commands = $$[QT_INSTALL_BINS]/lrelease-qt$${QT_MAJOR_VERSION} ${QMAKE_FILE_IN} |
|---|
| 78 | } else { |
|---|
| 79 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 80 | } |
|---|
| 81 | translations.CONFIG = no_link |
|---|
| 82 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 83 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 84 | |
|---|
| 85 | # Include 3rd party libraries |
|---|
| 86 | !handheld { |
|---|
| 87 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 88 | } |
|---|
| 89 | |
|---|
| 90 | win32:LIBS += -lole32 |
|---|
| 91 | |
|---|
| 92 | # Source |
|---|
| 93 | include(tspsg.pri) |
|---|
| 94 | |
|---|
| 95 | # Help |
|---|
| 96 | include(help/help.pri) |
|---|
| 97 | |
|---|
| 98 | # Code Documentation |
|---|
| 99 | include(doc/doc.pri) |
|---|
| 100 | |
|---|
| 101 | # Installation and deployment rules |
|---|
| 102 | include(install.pri) |
|---|
