| 1 | ###################################################################### |
|---|
| 2 | # |
|---|
| 3 | # TSPSG: TSP Solver and Generator |
|---|
| 4 | # Copyright (C) 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 5 | # |
|---|
| 6 | # $Id: $Format:%h %ai %an$ $ |
|---|
| 7 | # $URL: http://tspsg.info/ $ |
|---|
| 8 | # |
|---|
| 9 | # This file is part of TSPSG. |
|---|
| 10 | # |
|---|
| 11 | ###################################################################### |
|---|
| 12 | |
|---|
| 13 | !nosvg { |
|---|
| 14 | QT += svg |
|---|
| 15 | } else { |
|---|
| 16 | DEFINES += NOSVG |
|---|
| 17 | } |
|---|
| 18 | |
|---|
| 19 | greaterThan(QT_MAJOR_VERSION, 4) { |
|---|
| 20 | QT += printsupport concurrent |
|---|
| 21 | } |
|---|
| 22 | |
|---|
| 23 | wincewm*|symbian|maemo*|simulator|blackberry { |
|---|
| 24 | CONFIG += handheld |
|---|
| 25 | } |
|---|
| 26 | blackberry { |
|---|
| 27 | # DEFINES += QT_NO_SHORTCUT |
|---|
| 28 | DEFINES += QT_NO_PRINTDIALOG |
|---|
| 29 | DEFINES += QT_NO_PRINTPREVIEWDIALOG |
|---|
| 30 | |
|---|
| 31 | QT += xml declarative |
|---|
| 32 | LIBS += -lbb -lbbcascadespickers |
|---|
| 33 | } |
|---|
| 34 | |
|---|
| 35 | TEMPLATE = app |
|---|
| 36 | |
|---|
| 37 | # QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.5.sdk |
|---|
| 38 | |
|---|
| 39 | # Version information |
|---|
| 40 | QMAKE_TARGET_COMPANY = Oleksii Serdiuk |
|---|
| 41 | QMAKE_TARGET_PRODUCT = TSP Solver and Generator |
|---|
| 42 | QMAKE_TARGET_DESCRIPTION = TSPSG: TSP Solver and Generator |
|---|
| 43 | QMAKE_TARGET_COPYRIGHT = Copyright © 2007-2013 Oleksii Serdiuk <contacts[at]oleksii[dot]name> |
|---|
| 44 | |
|---|
| 45 | # Version detection |
|---|
| 46 | include(version.pri) |
|---|
| 47 | |
|---|
| 48 | DEFINES += BUILD_VERSION_MAJOR=$$BUILD_VERSION_MAJOR \ |
|---|
| 49 | BUILD_VERSION_MINOR=$$BUILD_VERSION_MINOR \ |
|---|
| 50 | BUILD_RELEASE=$$BUILD_RELEASE \ |
|---|
| 51 | BUILD_NUMBER=$$BUILD_NUMBER |
|---|
| 52 | |
|---|
| 53 | blackberry { |
|---|
| 54 | TARGET = tspsg |
|---|
| 55 | } else { |
|---|
| 56 | !debug_and_release|build_pass { |
|---|
| 57 | CONFIG(debug, debug|release) { |
|---|
| 58 | OBJECTS_DIR = debug |
|---|
| 59 | DEFINES += DEBUG |
|---|
| 60 | # CONFIG += console |
|---|
| 61 | D = d |
|---|
| 62 | } else { |
|---|
| 63 | OBJECTS_DIR = release |
|---|
| 64 | D = |
|---|
| 65 | } |
|---|
| 66 | } |
|---|
| 67 | } |
|---|
| 68 | |
|---|
| 69 | # Saving all intermediate files to tmp directory. |
|---|
| 70 | MOC_DIR = tmp |
|---|
| 71 | RCC_DIR = tmp |
|---|
| 72 | UI_DIR = tmp |
|---|
| 73 | |
|---|
| 74 | # We need to generate translations before building. |
|---|
| 75 | # Either way, resource files won't compile. |
|---|
| 76 | translations.name = Translations |
|---|
| 77 | translations.input = TRANSLATIONS |
|---|
| 78 | translations.output = $$_PRO_FILE_PWD_/l10n/${QMAKE_FILE_BASE}.qm |
|---|
| 79 | freebsd-* { |
|---|
| 80 | translations.commands = $$[QT_INSTALL_BINS]/lrelease-qt$${QT_MAJOR_VERSION} ${QMAKE_FILE_IN} |
|---|
| 81 | } else { |
|---|
| 82 | translations.commands = $$[QT_INSTALL_BINS]/lrelease ${QMAKE_FILE_IN} |
|---|
| 83 | } |
|---|
| 84 | translations.CONFIG = no_link |
|---|
| 85 | QMAKE_EXTRA_COMPILERS += translations |
|---|
| 86 | PRE_TARGETDEPS += compiler_translations_make_all |
|---|
| 87 | |
|---|
| 88 | # Include 3rd party libraries |
|---|
| 89 | !handheld { |
|---|
| 90 | include(src/3rdparty/qttoolbardialog-2.2_1-opensource/src/qttoolbardialog.pri) |
|---|
| 91 | } |
|---|
| 92 | |
|---|
| 93 | win32:LIBS += -lole32 |
|---|
| 94 | |
|---|
| 95 | # Source |
|---|
| 96 | include(tspsg.pri) |
|---|
| 97 | |
|---|
| 98 | # Help |
|---|
| 99 | include(help/help.pri) |
|---|
| 100 | |
|---|
| 101 | # Code Documentation |
|---|
| 102 | include(doc/doc.pri) |
|---|
| 103 | |
|---|
| 104 | # Installation and deployment rules |
|---|
| 105 | include(install.pri) |
|---|
